• Hilfe und Dokumentation

@echo off

TITLE TUD ARCHITEKTUR - VPN MTU FIX

REM ISLAM ADEL

REM 2025-08-15

echo.

echo TUD ARCHITEKTUR VPN MTU FIX

echo.

for /F "tokens=1* delims=: " %%a in ('powershell.exe Get-VpnConnection ^| FINDSTR /i "Name"') do (

	echo.

	echo vpn_name=%%b

	rem | Select-String $string -Context 3

	for /F "tokens=1* delims=: " %%d in ('powershell.exe "Get-VpnConnection -Name \"%%b\"" ^| FINDSTR /i "connect.architektur"') do (

		set vpn_server=%%e

		echo vpn_server=%%e

		IF NOT "%%e"=="" (

			for /F "tokens=1* delims=: " %%g in ('powershell.exe "Get-VpnConnection -Name \"%%b\"" ^| FINDSTR /i "Guid"') do (

				echo Guid=%%h

				echo.

				echo FIX MTU in REGISTRY

				rem 0x500 = 1280

				reg add "HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters\Interfaces\%%h" /t REG_DWORD /v "MTU" /d 0x500 /F

				set Guid=%%h

			)

		)

	)

)

IF "%vpn_server%"=="" (

	echo.

	echo.

	echo FEHLER: KEINE PASSENDE VPN VERBINDUNG GEFUNDEN

	echo bitte legen Sie zuerst die richtige VPN-Verbindung an

	echo.

	pause

	exit

)

rem verify

reg query "HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters\Interfaces\%Guid%" /v "MTU" | findstr 0x500

IF "%ERRORLEVEL%"=="0" (

	echo.

	echo Vorgang erfolgreich

	echo.

	echo BITTE STARTEN SIE DEN RECHNER JETZT NEU

) ELSE (

	echo.

	echo EIN FEHLER IST AUFGETRETEN

	echo VERSUCHEN SIE ES ERNEUT MIT Rechts-Klick und als Administrator ausfuehren

)

echo.

echo.

rem echo VORGANG ABGESCHLOSSEN

PAUSE